; tut_14a.csd
; macros de la partitura:
; macros simples
; ==============================================
sr = 48000
ksmps = 1
0dbfs = 1 ; amplitud máxima normalizada a 1
instr 1
iamp = ampdbfs(p4)
ifreq = cpspch(p5)
inarm = 18000/ifreq
imult = .85
asig gbuzz iamp, ifreq, inarm, 1, imult, 1
; parámetros de la serie de filtros resonanates
ifc1 = p6 ; frecuencia central
igain1 = ampdb(p7) ; resonancia
iq1 = p8 ; Q
ifc2 = p9
igain2 = ampdb(p10)
iq2 = p11
ifc3 = p12
igain3 = ampdb(p13)
iq3 = p14
ifc4 = p15
igain4 = ampdb(p16)
iq4 = p17
afilt1 pareq asig, ifc1, igain1, iq1, 0
afilt2 pareq afilt1, ifc2, igain2, iq2, 0
afilt3 pareq afilt2, ifc3, igain3, iq3, 0
afilt4 pareq afilt3, ifc4, igain4, iq4, 0
kamp linen 1, .02, p3, .15
aout = afilt4*kamp
out aout
endin
instr 2
iamp = ampdbfs(p4)
asig randi iamp, sr*.5, 0.5, 1
; parámetros de la serie de filtros resonanates
ifc1 = p5 ; frecuencia central
igain1 = ampdb(p6) ; resonancia
iq1 = p7 ; Q
ifc2 = p8
igain2 = ampdb(p9)
iq2 = p10
ifc3 = p11
igain3 = ampdb(p12)
iq3 = p13
ifc4 = p14
igain4 = ampdb(p15)
iq4 = p16
afilt tone asig, 1000
afilt1 pareq afilt, ifc1, igain1, iq1, 0
afilt2 pareq afilt1, ifc2, igain2, iq2, 0
afilt3 pareq afilt2, ifc3, igain3, iq3, 0
afilt4 pareq afilt3, ifc4, igain4, iq4, 0
kamp linen 1, .02, p3, .15
aout = afilt4*kamp
out aout
endin
; ==============================================
; coseno para gbuzz
f1 0 16384 11 1
#define BUZZ #i1#
#define RUIDO #i2#
; macros con los valores de las formantes
; 1 2 3 4
; frq amp Q frq amp Q frq amp Q frq amp Q
#define FILTRO1 #940 22 15 1800 20 16 3150 19 16 4900 17 20#
#define FILTRO2 #800 23 12 1400 20 15 3850 18 12 5900 20 12#
#define FILTRO3 #600 21 10 1900 18 17 2800 15 16 4800 17 16#
;p1 p2 p3 p4 p5
;instr init dur ampdB pch argumentos de los filtros
$BUZZ. 0 1.5 -11 7.10 $FILTRO1.
$BUZZ. + 1 -11 7.10 $FILTRO2.
$BUZZ. + 2 -11 7.10 $FILTRO3.
s
$RUIDO. 0 1.5 -14 $FILTRO1.
$RUIDO. + . -14 $FILTRO2.
$RUIDO. + . -14 $FILTRO3.
; última actualización: 2006-06-01 08:52